Value Required ID (\d+)
Value NAME (.*?)
Value ACTIVE_MEMBERS (\S+?)
Value INACTIVE_MEMBERS (\S+?)
Value BPDU (\S+?)
Value MODE (\S+?)
Value STATUS (Enabled|Disabled)
Value TYPE (Access|Trunk|)
Value LACP_KEY (\S+|)

Start
  ^${ID}\s+${NAME}\s+${ACTIVE_MEMBERS}\s+${BPDU}\s+${MODE}\s+${STATUS}\s*${TYPE}\s*${LACP_KEY}\s*$$ -> Record
  ^Id:\s+\d+\s*$$ -> Continue.Record
  ^Id:\s*${ID}\s*$$
  ^\s+Name:${NAME}\s*$$
  ^\s+Active Members:\s${ACTIVE_MEMBERS}\s*$$
  ^\s+Inactive Members:\s${INACTIVE_MEMBERS}\s*$$
  ^\s+Bpdu:\s${BPDU}\s*$$
  ^\s+Mode:\s${MODE}\s*$$
  ^\s+Status:\s${STATUS}\s*$$
  ^\s+Type:\s${TYPE}\s*$$
  ^\s+LACP key:\s${LACP_KEY}\s*$$
  ^\s+LACP$$
  ^Id\s+Name\s+Members\s+Bpdu\s+Mode\s+Status\s+Type(\s+Key|)\s*$$
  ^-+\s+-+\s+-+\s+-+\s+-+\s+-+\s+-+(\s+-+|)\s*$$
  ^MODE\s+Legend:\s*$$
  ^B=Basic,\s+A=Advance,\s+Man=ManLag,\s+Dyn=DynLag\s*$$
  ^.*$$ -> Error
