Value Filldown,Required ROUTER_ID ([0-9a-f:\.]+)
Value Filldown LOCAL_AS (\d+(\.\d+)?)
Value Filldown ADDRESS_FAMILY (.+?)
Value BGP_NEIGHBOR (\d+?\.\d+?\.\d+?\.\d+?)
Value BGP_VERSION (\d+)
Value NEIGHBOR_AS (\d+(\.\d+)?)
Value MESSAGES_RECEIVED (\d+)
Value MESSAGES_SENT (\d+)
Value TABLE_VERSION (\d+)
Value INPUT_QUEUE (\d+)
Value OUTPUT_QUEUE (\d+)
Value UP_DOWN (\S+?)
Value STATE_OR_PREFIXES_RECEIVED (\S+?\s+\S+?|\S+?)

Start
  ^For\s+address\s+family:\s+${ADDRESS_FAMILY}$$
  ^BGP\s+router\s+identifier\s+${ROUTER_ID},\s+local\s+AS\s+number\s+${LOCAL_AS}\s*$$
  ^${BGP_NEIGHBOR}\s+${BGP_VERSION}\s+${NEIGHBOR_AS}\s+${MESSAGES_RECEIVED}\s+${MESSAGES_SENT}\s+${TABLE_VERSION}\s+${INPUT_QUEUE}\s+${OUTPUT_QUEUE}\s+${UP_DOWN}\s+${STATE_OR_PREFIXES_RECEIVED}\s*$$ -> Record
  # Capture time-stamp if vty line has command time-stamping turned on
  ^Load\s+for\s+
  ^Time\s+source\s+is

EOF