Value Filldown VR (\S+)
Value BEST (\S+)
Value ID (\d+)
Value Required IP_ADDRESS (\d+(\.\d+){3})
Value Required PREFIX_LENGTH (\d{1,2})
Value OUTINTERFACE (\S+)
Value NEXTHOP (\d{1,3}\.\d{1,3}\.\d{1,3}\.\d{1,3})
Value PROTOCOL (\S+)
Value PREF (\d+)
Value METRIC (\d+)
Value VSYS (\S+)

Start
  # Match the VR
  ^IPv\d\s+Dest-Routes\s+for\s+<${VR}>
  # Match route line
  ^${BEST}\s+${ID}\s+${IP_ADDRESS}\/${PREFIX_LENGTH}\s+${OUTINTERFACE}\s+${NEXTHOP}\s+${PROTOCOL}\s+${PREF}\s+${METRIC}\s+${VSYS} -> Record
  # Match table separator
  ^-+\s*$$
  # Match route type keys
  ^\S+:\s+
  # Match lines that are just space
  ^\s+$$
  # Match table header
  ^\s+ID\s+IP-Prefix\s+Interface\s+Gateway\s+P\s+Pref\s+Mtr\s+Vsys\s*$$
  # Error out if line does not match any expressions
  ^.+ -> Error "Line not found"

EOF
